Problem

Ein mit …

DBE textList = listView (...);

… erstelltes UI Element, welches eine Tabelle / Liste (mit/ohne Checkboxen) präsentiert, soll durchlaufen werden ohne eine separate Datenstruktur befüllen zu müssen.

An iteration through a listView(…) UI element shall be performed without the need of an additional data structure.

Ansatz – Approach

The following functions can be used to perform an Iteration…
int noElems(DBE element) – liefert die Anzahl der Elemente in einer UI Liste (element: choice, tab strip, list, multi-list, combo box, or list view)
bool getCheck(DBE listView, index) – liefert einen BOOL ob die Checkbox (falls vorhanden) im Eintrag markiert ist
string getColumnValue(DBE listView, int row, int column) – liefert den Content der Spalte

Lösung – Solution

// Iteriere über eine Liste / Tabelle des Typs listView: Welche... Datenstruktur oder UI Element?
// textList = listView (...);
int i = 0;
	
for (i = 0; i < noElems(textList); i++)
{
	// if the entry is checked (selected) ...
	if (getCheck(textList, i))
	{
		
		string textID_StringValue = getColumnValue(textList,i,0);
		string currentDoors_StringValue = getColumnValue(textList,i,1);
		string currentWings_StringValue = getColumnValue(textList,i,2);
		string textFile_StringValue = getColumnValue(textList,i,3);
		string module_StringValue = getColumnValue(textList,i,4);
	}
}

Aufgabe

Alle eingeloggten User eines Modules sollen ausgegeben werden / Alle User Sessions angzeigt werden

Ansatz

Auslesen der Session History

Lösung

Module m = read("/NDS/20 System/RS-System Requirements Specification");
HistorySession hs = null;


for hs in m do
{
	print number(hs) "," when(hs) "," who(hs) ",";

	string sBaseline=baseline(hs);
	if(sBaseline != null)
	{
		print sBaseline;
	}
	print "\n";
}

Problem

The links in a link module should be iterated

Approach

Link Modules can be read with the appropriate method like formal modules.

Solution

nSatisfiesLinkModule = "/NDS/90 Administration/Satisfies"; 
Object o = null; 
string src   = ""; 
string tgt   = ""; 
SatisfiesLinkModule = read(nSatisfiesLinkModule, false); 
for o in SatisfiesLinkModule do 
{ 
                // get names of source and target modules 
                src = o."source" "" 
                tgt = o."target" "" 
                print src " -> " tgt "\n" 
}

Problem

The modification (Edit Mode / Edit Share) of a module shall be prevented.
Das Editieren eine Doors Modules (Edit Mode / Share Mode) soll verhindert werden.

Approach

Defining a library and using the existence of a trigger as condition for allowed modifications can be used to block the formal Module for edit/share mode.
Durch das definieren eine Triggers und der zugehörigen Trigger_Library kann man die Existenz eines Triggers als Bedingung für das Erlauben des Edit/Share Modes nehmen.

Solution

void listAllTriggerForMod (Module mod) 
{
	Trigger t;
	for t in mod do 
	{
		print name(t) "\n";	
	}
}

bool checkTriggerIfExistForMod (Module mod, string triggername) 
{
	Trigger t;
	for t in mod do 
	{
		if(name(t) "" == triggername)	
		{
			return true;
		}
	}
	
	return false;
}

string getDXLCodeForModWithTrigger (Module mod, string triggername) 
{
	Trigger t;
	for t in mod do 
	{
		if(name(t) "" == triggername)	
		{
			return dxl(t);
		}
	}
	
	return "not found";
}

void removeTriggerForModWithName(Module mod, string triggername) {

	Trigger t;
	string errorMsg;
	
	// first delete _all possible trigger_
	for t in mod do {
		if (name (t) "" == triggername) {
			errorMsg = delete(t);
		   	if(!null(errorMsg)) {
			  errorBox("Error occurred:\n" errorMsg"");
			  break;
		   }
		}
	}
}

void installTriggerForMod (Module mod) 
{
	string dxlCode = "Module cm = current Module;\n" //-
					"if ((isEdit(cm)||isShare(cm))){\n" //-
					"ack(\"During Wings LDT modifications it is not allowed to modify texts in the UIT/ALM Module.\");\n" //-
					"downgrade(cm)\n" //-
					"}\n";
	 
	string errors = checkDXL(dxlCode)
	
	if(null(errors)) 
	{
		string moduleName = name(mod)
		if(!checkTriggerIfExistForMod(mod, "Text_Tool_Block_Trigger"))
		{
			Trigger t = trigger("Text_Tool_Block_Trigger", project->module->moduleName, post, open, 15, dxlCode);
		}
		else ack "Trigger already exist!";
	}
	
	save(mod);
}

Module uitModule = read("/NDS/20 System/DS/UIT-User Interface Texts", false);
print "Vor der Installation...\n";
print "=======================\n";
listAllTriggerForMod(uitModule);
installTriggerForMod(uitModule);
print "\n\nNach der Installation...\n";
print "=======================\n";
listAllTriggerForMod(uitModule);
removeTriggerForModWithName(uitModule, "Text_Tool_Block_Trigger");
print "\n\nNach dem Entfernen...\n";
print "=======================\n";
listAllTriggerForMod(uitModule);

Problem

Some Triggers have been defined on a module and the names should be listed.

Approach

Defining a variable from Type Trigger as cursor allows us to get each trigger on the current module.

Solution

Module mod=current Module
Trigger t;
for t in mod do {
	print name(t) "\n";	
}